globals [
  initial-trees   ;; how many trees (green patches) we started with
  burned-trees    ;; how many have burned so far
]

patches-own [
  burned?         ;; has this tree burned yet?
]

to setup
  ca
  ask patches
    [ set burned? false
      ;; put a wall around the forest to prevent "wrapping"
      if (pxcor = (0 - screen-edge-x)) or
         (pycor = (0 - screen-edge-y)) or
         (pycor = screen-edge-y) 
        [ set pcolor blue ]
      ;; make some green trees
      if pcolor != blue and pxcor > (1 - screen-edge-x) 
        [ if (random 100) < density 
          [ set pcolor green ] ]
      ;; make a column of burning trees
      if pcolor != blue and pxcor = (1 - screen-edge-y) 
        [ set pcolor red
          set burned? true ] ]
  set initial-trees count patches with [pcolor = green]
  set burned-trees 0
end

to go
  if not any patches with [burning?]
    [ stop ]
  ask patches with [pcolor = green]
    [ if any neighbors4 with [burned?]
        [ set pcolor red
          set burned-trees burned-trees + 1 ] ]
  ;; having these two separate "ask patches" commands
  ;; ensures that all patches have inspected their
  ;; neighbors' burned? variable before any newly
  ;; burned patches set that variable to true -- this
  ;; ensures that the fire only spreads a distance of
  ;; one patch per turn
  ask patches with [burning?]
    [ set burned? true
      set pcolor pcolor - 0.3 ]
end

to-report burning?  ;; patch procedure
  report (pcolor > (red - 4)) and (pcolor < (red + 1))
end

to-report percent-burned
  ifelse initial-trees > 0
    [ report (burned-trees / initial-trees) * 100 ]
    [ report 0 ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Fire model.
; http://ccl.northwestern.edu/netlogo/models/Fire.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
257
10
694
468
30
30
7.0
1
10
0
0

CC-WINDOW
5
313
252
469
Command Center

MONITOR
67
190
182
239
percent burned
percent-burned
1
1

SLIDER
5
101
252
134
density
density
0.0
99.0
57.0
1.0
1
%

BUTTON
137
54
206
90
go
go
T
1
T
OBSERVER

BUTTON
57
54
127
90
setup
setup
NIL
1
T
OBSERVER

@#$#@#$#@
WHAT IS IT?
-----------
This project simulates the spread of a fire through a forest. The fire starts on the left edge of the forest, and spreads to neighboring trees. The fire spreads in four directions: north, east, south, and west. 

There is no wind in this particular model as it is.  So, the fire must have trees along its path in order to advance.  That is, the fire cannot skip over an unwooded area (patch), so such a patch blocks the fire's motion in that specific direction

The fire's chance of reaching the right edge of the forest depends critically on the density of trees in the forest.


HOW TO USE IT
-------------
Click the SETUP button to set up the trees (green) and fire (red on the left-hand side).

Click the GO button to start the simulation.

The DENSITY slider controls the density of trees in the forest. (Note: Changes in the DENSITY slider do not take effect until the next SETUP.)


THINGS TO NOTICE
----------------
Set the density of trees to 55%. At this setting, there is virtually no chance that the fire will reach the right edge of the forest. Set the density of trees to 70%. At this setting, it is almost certain that the fire will reach the right edge. There is a sharp transition around 59% density. At 59% density, the fire has a 50/50 chance of reaching the right edge.

The blue "walls" prevent the fire from spreading off the edges of the screen.

Because no turtles are moving on the screen, one could say that the motion of the fire is a construction in our mind.  This is an example of an emergent phenomena: each tree is either burning or not burning, but these collective local behaviors amount to an overall effect.  The effect (moving fire) is created by the local agents (trees, here), even though it is not experienced by the local agents.  So is an emergent phenomenon the same as an optical illusion? That is, do you think that the motion of fire is an optical illusion?  Is this the same as the illusion of motion running through a sequence of flashing neon lights?  If not, why not?  Arguably, there is no "thing" running along the neon lights - just lights flashing.  So, is fire a "thing" at all?  If not, then how can it move?  Moreover, how can it burn?


EXTENDING THE MODEL
-------------------
What if the fire could spread in eight directions (including diagonals)? To do that, use "neighbors" instead of "neighbors4". How would that change the fire's chances of reaching the right edge? In this model, what "critical density" of trees is needed for the fire to propagate? 

Add wind to the model so that the fire can "jump" greater distances in certain directions.


NETLOGO FEATURES
-----------------
This project uses only patches, no turtles. Each tree uses the "neighbors4" primitive to determine whether any of the surrounding trees are on fire.

Notice how the program gradually decreases the patch color of the red patches to achieve the visual effect of burning out.


CREDITS AND REFERENCES
----------------------
This model was developed at the MIT Media Lab. See Resnick, M. (1994) "Turtles, Termites and Traffic Jams: Explorations in Massively Parallel Microworlds." Cambridge, Ma: MIT Press. Adapted to StarLogoT, 1997, as part of the Connected Mathematics Project. Adapted to NetLogo, 2000, as part of the Participatory Simulations Project.

To refer to this model in academic publications, please use: Wilensky, U. (1998).  NetLogo Fire model. http://ccl.northwestern.edu/netlogo/models/Fire. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

@#$#@#$#@
NetLogo 1.3
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@